Introduction

In this article, I’ll introduce UEFN’s experimental new feature, Scene Graph. Scene Graph is not yet officially released and cannot be used in public maps, but it’s expected to become available eventually (really?).

With Scene Graph, you can:

• Automatically generate code‑enabled objects
• Perform collision detection (hit testing) and raycasts

These features were previously impossible in UEFN. In particular, hearing that collision detection would become possible sparked my strong interest in Scene Graph. However, since it’s still in beta, there are almost no comprehensive tutorials or guides 😭

Therefore, in this article I’ll explain the basic usage of Scene Graph, focusing primarily on Verse. If you’re curious about Scene Graph or want to explore new possibilities in UEFN, please read through to the end — Scene Graph is fun!

‍

Final Result

‍

raycast_component

using { /Verse.org }
using { /Verse.org/Native }
using { /Verse.org/SceneGraph }
using { /Verse.org/Simulation }
using { /Fortnite.com/Devices }
using { /Fortnite.com/Characters }
using { /Verse.org/SpatialMath }
using { /UnrealEngine.com/Temporary/SpatialMath }
using { /UnrealEngine.com/Temporary/Diagnostics }
using { /Verse.org/SceneGraph/KeyframedMovement }
using { /Verse.org/Colors/NamedColors }


my_debug_draw := class(debug_draw_channel){}

raycast_component<public> := class<final_super>(component):

    # Debug
    DebugDraw : debug_draw = debug_draw{Channel := my_debug_draw}

    OnSimulate<override>()<suspends>:void =
        {}

    # Returns hit location and normal
    SearchHit(Player : player):tuple(?(/Verse.org/SpatialMath:)vector3, ?(/Verse.org/SpatialMath:)vector3)=
        var ReturnValue : tuple(?(/Verse.org/SpatialMath:)vector3, ?(/Verse.org/SpatialMath:)vector3) = (false, false)
        
        if(Char := Player.GetFortCharacter[]) :
            Print("Collision search")
            # Calculate player's view direction
            LookRot :[]float= Char.GetViewRotation().GetYawPitchRollDegrees()
            if :
                YawRadian := (/UnrealEngine.com/Temporary/SpatialMath:)DegreesToRadians(LookRot[0])
                PitchRadian := (/UnrealEngine.com/Temporary/SpatialMath:)DegreesToRadians(LookRot[1])
            then :
                LookDirection := (/UnrealEngine.com/Temporary/SpatialMath:)vector3{X := Cos(YawRadian)*Cos(PitchRadian), Y := Sin(YawRadian)*Cos(PitchRadian), Z := Sin(PitchRadian)}
                # Set collision check distance (cm; use very large value for infinite range)
                Range := 2000.0
                DisplacementRange := LookDirection*Range
                # Start position for collision check
                ViewLoc := FromVector3(Char.GetViewLocation())
                # Collision (HitResult occurs when this collides)
                Collision : collision_sphere = collision_sphere :
                    Radius := 1.0
                # Check if sweep collision hits anything
                # HitResult occurs if collision detected
                HitResult := Entity.FindSweepHits(FromVector3(DisplacementRange), (/Verse.org/SpatialMath:)transform{Translation := ViewLoc}, Collision)
                DebugDraw.DrawLine(Char.GetViewLocation(), Char.GetViewLocation()+DisplacementRange, ?Duration:= 2.0)

                var IsHit : logic = false
                for(Result : HitResult) :
                    ParentEntity := Result.TargetComponent.Entity
                    # Treat as wall hit if no raycast_component
                    # Optionally, differentiate walls by using a specific component
                    if(IsHit = false, not ParentEntity.GetComponent[raycast_component]) :
                        # Perform hit detection only once (when IsHit is false)
                        set IsHit = true
                        HitPos := Result.ContactPosition
                        HitNormal := Result.ContactNormal
                        # Set return value
                        set ReturnValue = (option{HitPos}, option{HitNormal})
                        # Debug
                        DebugDraw.DrawSphere(FromVector3(HitPos), ?Radius := 10.0, ?Duration:= 2.0)
                        DebugDraw.DrawLine(FromVector3(HitPos), FromVector3(HitPos + HitNormal*100.0),?Color := Red,  ?Duration:= 2.0)
                        Print("Hit : {HitPos}")

        return ReturnValue

‍

portal_component

using { /Verse.org }
using { /Verse.org/Native }
using { /Verse.org/SceneGraph }
using { /Verse.org/Simulation }
using { /Fortnite.com/Devices }
using { /Fortnite.com/Characters }
using { /Verse.org/SpatialMath }
using { /UnrealEngine.com/Temporary/SpatialMath }

portal_component<public> := class<final_super>(component):

    @editable CondButton_Remocon : conditional_button_device = conditional_button_device{}
    @editable RemoconManager : signal_remote_manager_device = signal_remote_manager_device{}

    var IsTeleportPos : ?(/Verse.org/SpatialMath:)vector3 = false
    var PortalE : entity = entity{}

    OnSimulate<override>()<suspends>:void =
        set PortalE = entity{}
        RemoconManager.PrimarySignalEvent.Subscribe(OnSignal_Fire)
        RemoconManager.SecondarySignalEvent.Subscribe(OnSignal_Aim)

    OnSignal_Fire(Agent :agent):void=
        if :
            Char : fort_character = Agent.GetFortCharacter[]
            TeleportPos : (/Verse.org/SpatialMath:)vector3 = IsTeleportPos?
            Char.TeleportTo[FromVector3(TeleportPos), Char.GetTransform().Rotation]
        then :
            set IsTeleportPos = false
            RemovePortalVFX()
            Print("Teleport")
        else :
            Print("Teleport failed")

    OnSignal_Aim(Agent :agent):void=
        if :
            Player : player = player[Agent]
            RayComp := Entity.GetComponent[raycast_component]
        then :
            Result := RayComp.SearchHit(Player)
            if :
                HitPos :(/Verse.org/SpatialMath:)vector3= Result(0)?
                HitNormal :(/Verse.org/SpatialMath:)vector3= Result(1)?
            then :
                TeleportPos := HitPos + HitNormal*100.0
                set IsTeleportPos = option{TeleportPos}
                AddPortalVFX(TeleportPos)
                Print("Teleport destination registered")
            else :
                set IsTeleportPos = false
                RemovePortalVFX()
                Print("No teleport destination")

    AddPortalVFX(SpawnPos : (/Verse.org/SpatialMath:)vector3):void=
        RemovePortalVFX()
        NewE := entity{}
        VFXComp : particle_system_component = Niagara.NS_Portal :
            Entity := NewE
            AutoPlay := true
        NewE.AddComponents(array{VFXComp})
        set PortalE = NewE
        if(Scene := Entity.GetSimulationEntity[]) :
            Scene.AddEntities(array{PortalE})
            PortalE.SetGlobalTransform((/Verse.org/SpatialMath:)transform{Translation := SpawnPos})

    RemovePortalVFX():void=
        PortalE.RemoveFromParent()

‍

Setup of Triggers and Entities

• Signal Remote Manager (signal_remote_manager_device)
• Signal Remote
• Conditional Button (conditional_button_device)
• Entity (with raycast_component and portal_component attached)

‍

Scene Graph Basics

Many people haven’t tried Scene Graph before, so here’s a quick overview of the core concepts. Feel free to skip if you’re already familiar.

Enabling Scene Graph

Scene Graph is an experimental feature, so you must enable it on a per-project basis (as of March 21, 2025):

1. Open the Project menu
2. Select Project Settings
3. Enable the SceneGraph System checkbox

‍

Right‑click in an empty area of the Content Drawer
↓
select Entity Prefab Definition

Open the prefab you created
↓
Select ①
↓
Select ②

A dropdown menu will appear, allowing you to choose which component to add.

• Each entity can only have one of the same component type. If you need multiple mesh components, create additional entities accordingly.
• To add a new entity, hover over ① and right‑click.

• Place the prefab into the level.

Drag and drop the prefab from the Content Drawer into the viewport.

‍

• For those who prefer to see the whole process in action, check out the video below.

‍

‍

Animation

Let’s try writing some simple code to make an entity move back and forth in place.

However, you (probably) can’t use MoveTo with entities.
Instead, you can add a component called keyframed_movement_component to the entity, which you'll control from the Verse side.

【Overall Workflow】

• Add both keyframed_movement_component and a custom Verse component to the entity.
• From the Verse component, get a reference to the keyframed_movement_component, create the animation, and play it.

Let’s Go Through the Steps in Detail

First, create an entity prefab and add the following components:

• mesh_component
• transform_component
• keyframed_movement_component

Next, create a new Verse file from the New Verse Component menu and name it move_component.
(This component will be automatically added to the entity.)

‍

Now, open move_component from the Verse file.

Let’s go through it step by step!

With @editable, you can add variables that can be edited per instance.
Just like in standard Verse (such as in UEFN 1.0), you can assign values like devices or triggers in the usual way.

‍

The OnSimulate() function is called the moment this entity is spawned.
So, if you call a function from here, you can see the result even while in Edit mode — no need to start the game.

There’s no need for something like OnBeginSimulation().

‍

You can access the parent entity of this component by using Entity.
Entity is of type entity, and you can check whether it has a specific component by using:

Entity.GetComponent[ComponentType]


If the entity doesn’t have that component, it returns false.

In this case, we're retrieving the keyframed_movement_component.
This component provides APIs like Play() and SetKeyframes(), and you can use it similarly to an AnimationController in Verse.

‍

Since we want the entity to move back and forth, we simply move it forward and then move it back by the same amount (using -MoveAmount).

‍

Spawning and Destroying Entities

In this world, there’s something called the root entity.New entities can be spawned by attaching them to this root entity — kind of like setting up a parent-child relationship.

To try it out, create a new prefab, then go to New Verse File and name it spawner_component.

Let’s go through it step by step!

• NewEntity

This is where we prepare the entity we want to spawn.We create an array of components we want to add, and use AddComponents to attach them to the entity.

• Entity.GetSimulationEntity[]

Here, we're getting the root entity that we mentioned at the beginning of this section.
Using Scene.AddEntities(), we add the entity we prepared earlier.

Note: AddEntities expects an array of entity types as its argument, so make sure to pass something like array{entity}.

With this, entities will now keep spawning upward one after another!

‍

• Entity.RemoveFromParent()

You can remove an entity from the world by calling .RemoveFromParent() on the entity you want to delete.

‍

Assigning Materials and Changing Parameters

Assigning materials works a bit differently.
You need to specify the material slot on the mesh where the material should be applied.

Because of this, you likely can’t change materials on a regular mesh_component
— since it doesn’t reference a specific asset.

So instead, we can spawn a new entity
—or add a mesh_component to the current entity
—because in that case, the mesh_component references a specific asset,which means we can assign a material to it!

Also, if you want to use variables like material or entity types across multiple functions,
you’ll need to reinitialize them once inside OnSimulate()
‍— otherwise, things might not work as expected.(Why? Honestly, not sure either.)

Well, once you’ve assigned the material, you can modify its parameters just by working with the material variable itself
—so technically, it’s fine after that… but still, yeah.

‍

Collision Detection

There are four main APIs you can use for collision detection:

• Entity.FindOverlapHits

Checks if the entity is currently overlapping with any other entities,
or if any entities exist within a certain collision range from the entity.

• Entity.FindSweepHits

Checks if there are any entities within a specified distance (Displacement) from a starting position.

⚠️ FindSweepHits works by virtually sliding the entity’s mesh component along a straight path to see if it hits anything.
That means you need to either pass in a collision shape as an argument, or make sure the entity has a mesh component — otherwise, it won't work.

✔️ If you make the mesh component (or collision shape) very small,
you can use this function like a pseudo line trace.

🧭 Displacement must include both direction and distance —
in other words, Displacement = DirectionVector * Distance.

• MeshComponent.EntityEnteredEvent

A listenable event that fires when another entity overlaps with this mesh component.

• MeshComponent.EntityExitedEvent

A listenable event that fires when another entity leaves this mesh component’s collision area.

As an example, here’s some code that performs a collision check 2000cm in the direction the player is looking:

If you're using both of the following imports in the same Verse file:

• using { /Verse.org/SpatialMath }

• using { /UnrealEngine.com/Temporary/SpatialMath }

Verse might get confused about which one to use.
To fix that, make sure to specify clearly which version you're referencing — like in the example below.

‍

[Advanced] Let’s Build a Teleport System

Based on everything we’ve covered so far, let’s try creating a simple teleport system!

Requirements:

• When the player presses the secondary fire button (aim) on the signal remote,
  a portal appears in the direction they’re looking, within a 2000cm range.
• When the player presses the primary fire button (shoot),
  they’ll teleport to the previously placed portal.
• The portal must not spawn inside another object.
  (We won’t worry about moving platforms or dynamic obstacles for now.)
• When a new portal is placed, any existing portal is removed.
  Also, once a portal is used, it disappears.

The full code and setup will be provided at the end of this article!